Verständnisproblem bei verschachtelten Operatoren

Antwort erstellen


Um automatische Eingaben zu unterbinden, musst du die nachfolgende Aufgabe lösen.

BBCode ist eingeschaltet
[img] ist ausgeschaltet
[flash] ist ausgeschaltet
[url] ist eingeschaltet
Smilies sind ausgeschaltet

Die letzten Beiträge des Themas
   

Ansicht erweitern Die letzten Beiträge des Themas: Verständnisproblem bei verschachtelten Operatoren

Re: Verständnisproblem bei verschachtelten Operatoren

von fratso » Mo, 14.05.2018 18:30

Aufgabe gelöst! Ich danke herzlich für die beiden schnellen Antworten.

Frank

Re: Verständnisproblem bei verschachtelten Operatoren

von lorbass » Mo, 14.05.2018 17:46

Bei derartigen Gelegenheiten gehe ich etwa so vor:

Im ersten Schritt kopiere ich deine Formeln in eine Textdatei, die ich mit 'nem normelane Text-Editor bearbeiten kann. Dort bringe ich ein bisschen Struktur in die WENN-Formel:

Code: Alles auswählen

=WENN(I83="ganz_oben";
  "-";
  ""
)
WENN(UND(H83=0;G83>=0,5);
  "oben";
  ""
)
WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));
  "fast_unten";
  ""
)
WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));
  "ganz_unten";
  ""
)
Danach ersetze die leere Zeichenkette (»""«) im SONST-Zweig durch die komplette nächste WENN-Funktion:

Code: Alles auswählen

=WENN(I83="ganz_oben";
  "-";
  WENN(UND(H83=0;G83>=0,5);
    "oben";
    WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));
      "fast_unten";
      WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));
        "ganz_unten";
        ""
      )
    )
  )
)
Das kann ich dann so, wie's dasteht, in eine Calc-Zelle kopieren. Alternativ kann ich die Struktur wieder rausnehmen und die Formel als eine einzige Zeile nach Calc transportieren:

Code: Alles auswählen

=WENN(I83="ganz_oben";"-";WENN(UND(H83=0;G83>=0,5);"oben";WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";""))))
Um die Logik das Ganzen hab ich mich hier allerdings nicht gekümmert, weil ich keinen blassen Schimmer davon habe, was in den diversen Zellen steht und was in welchem Fall als Ergbnis rauskommen soll.

Gruß
lorbass

Re: Verständnisproblem bei verschachtelten Operatoren

von Mondblatt24 » Mo, 14.05.2018 17:20

Hallo,

Code: Alles auswählen

WENN(I83="ganz_oben";"-";WENN(UND(H83=0;G83>=0,5);"oben";WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";""))))

Gruß Peter

Verständnisproblem bei verschachtelten Operatoren

von fratso » Mo, 14.05.2018 16:47

Moin!

Ich versuche, folgende Zeilen in eine zu packen; leider mit mäßigem Erfolg.

=WENN(I83="ganz_oben";"-";"")
=WENN(UND(H83=0;G83>=0,5);"oben";"")
=WENN(UND(G83<0,5;(ODER(J82="oben";J82="fast_unten")));"fast_unten";"")
=WENN(UND(G83>=G82+0,25;(ODER(J91="-";J91="ganz_unten")));"ganz_unten";"")

Weiß hier jemand Rat?

Gruß

Frank

Nach oben