Hallo Cracks,
Die Überschrift beschreibt nicht ganz wie verzweifelt ich bin. Ich suche seit, zwischenzeitlich 8 Monaten, nach einer Formel die mir berechnet wie viele Teile ich aus Grundmaterialien wie Gold, Silber und Platin herstellen kann. meine Formel(n) die ich bis heute gefunden bzw. gebastelt habe, wenn auch mit hilfe von anderen, ist nicht ganz vollständig.
A4 = Gold, B4= Silber und C4=Platin
Meine erste Formel
=WENN($A$4<>A10;WENN($B$4<>B10;WENN($C$4<>C10;MIN($A$4/A10;$B$4/B10;$C$4/C10))))
2. Formel
=WENN($A$4>=A10;WENN($B$4>=B10;WENN($C$4>=C10;ABRUNDEN(MIN($A$4/A10;$B$4/B10;$C$4/C10);0);0);0);0)
Das resultat soll nur ganze Zahlen ausgeben auch dann wenn ein Rohstoff nicht verwendet wird. Leider bekomme ich die Fehlermeldung #DIV/0! beim fehlen eines Rohstoffs, ich kapier nur nicht wo der Fehler liegt. Sind die Formeln eventuell auch vollkommen murks?? Ich weiß es einfach nicht. Ich hoffe ihr könnt mir helfen.
Gruß Axel
Wenn Funktion 3 Werte
Moderator: Moderatoren
Re: Wenn Funktion 3 Werte
Hallo,
Du teilst durch A10, B10, und C10 in Deinen Formeln,
also bekommst Du einen Div/0-Fehler, wenn eine dieser Zellen 0 enthält.
Wenn Du das nicht willst musst Du die Division vermeiden, wenn da eine 0 steht.
Bei Deinen Formeln kann man Dir schlecht helfen, da nicht klar ist, was in den Zeilen
4nund 10 steht, was Du unter einem Teil verstehst und warum das Ganzzahlige Werte sein sollen.
Bei mir wurde Platin immrr mit 3 Nachkommastellen abgewogen.
MfG, Jörn
Du teilst durch A10, B10, und C10 in Deinen Formeln,
also bekommst Du einen Div/0-Fehler, wenn eine dieser Zellen 0 enthält.
Wenn Du das nicht willst musst Du die Division vermeiden, wenn da eine 0 steht.
Bei Deinen Formeln kann man Dir schlecht helfen, da nicht klar ist, was in den Zeilen
4nund 10 steht, was Du unter einem Teil verstehst und warum das Ganzzahlige Werte sein sollen.
Bei mir wurde Platin immrr mit 3 Nachkommastellen abgewogen.
MfG, Jörn
Libre Office 6.3.1 (Win 10 Pro) / Libre Office 6.0.7 (Win8.1 Pro, Win 7 Pro) / AOO (Win 7)
-
- **
- Beiträge: 29
- Registriert: Sa, 26.04.2014 11:37
Re: Wenn Funktion 3 Werte
In A4 bis C4 Steht der Lagerbestand und in den Zeilen A10 bis C10 ist die Menge angegeben die EIN Schmuckstück verbraucht.In Zeile F10 soll nun, ohne nachkomme stellen, ausgerechnet werden wie viele Schmuckstucke ich von angegebenen Lagerbestand bekommen kann.
Re: Wenn Funktion 3 Werte
Naja, dann würde ich das schrittweise entwickeln.In A4 bis C4 Steht der Lagerbestand und in den Zeilen A10 bis C10 ist die Menge angegeben die EIN Schmuckstück verbraucht.In Zeile F10 soll nun, ohne nachkomme stellen, ausgerechnet werden wie viele Schmuckstucke ich von angegebenen Lagerbestand bekommen kann.
die Materialposition A reicht für A4/A10 Schmuckstücke, schreibe das z.B. in A12:
=A4/A10
nun geht es aber nur um ganzzahlige Werte die gleichgroß oder kleiner sein dürfen als dieser Wert in A12, also schreibe in A13:
=GANZZAHL(A12)
nun setze A12 in A13 ein:
=GANZZAHL(A4/A10)
nun schreibe Selbiges für Positionen B und C in B13 und C13:
B13: =GANZZAHL(B4/B10)
C13: =GANZZAHL(C4/C10)
gesucht ist nun der kleinste Wert aus A13 bis C13 denn er entspricht dem maximalen Wert wie viele Schmuckstücke mit dem vorhandenen Material hergestellt werden können, sagen wir in A14:
=MIN(A13;B13;C13)
A13 bis C13 können nun jeweil "#DIV/0!" enthalten wenn A10 bis C10 Null sind, also fange diesen Fehler ab. Die Formel schreibst Du in A15:
=WENN(ISTFEHLER(A14);"";A14)
nun ersetze in A15 die Angabe A14 durch das was in A14 steht, also schreibne z.B. in A16:
=WENN(ISTFEHLER(MIN(A13;B13;C13));"";MIN(A13;B13;C13))
und ersetze hierin wieder A13 bis C13 durch den Inhalt dieser Zellen und schreibe das z.B. in A17:
=WENN(ISTFEHLER(MIN(GANZZAHL(A4/A10);GANZZAHL(B4/B10);GANZZAHL(C4/C10)));"";MIN(GANZZAHL(A4/A10);GANZZAHL(B4/B10);GANZZAHL(C4/C10)))
diese Formel aus A17 kannst Du nun in eine beliebige Zelle kopieren wo Du das Ergebnis haben willst und anschließend kannst Du alle 'Zwischenformel' wieder löschen, denn sie werden nicht mehr gebraucht.
zuletzt könntest die Formel auch noch etwas kürzen, aber das ist keine funktionelle Frage, sondern nur eine kürzere Schreibung, z.B.:
=WENN(ISTFEHLER(GANZZAHL(MIN((A4/A10);(B4/B10);(C4/C10))));"";GANZZAHL(MIN((A4/A10);(B4/B10);(C4/C10))))
Gruß
Stephan
Re: Wenn Funktion 3 Werte
Hallo zusammen,
@Stephan
ich vermute du hast überlesen das die Formel auch dann einen Wert ausgeben soll,
wenn nur ein oder zwei der Materialien angegeben werden / im Bedarf angegeben sind.
Da habe ich jetzt noch etwas weiter getüfftelt und nun eine Formel erstellt die so hoffe ich, alle Wünsche von Axel berücksichtigt.
hier eine Beispieldatei
Viel Spaß
@Stephan
ich vermute du hast überlesen das die Formel auch dann einen Wert ausgeben soll,
wenn nur ein oder zwei der Materialien angegeben werden / im Bedarf angegeben sind.
Da habe ich jetzt noch etwas weiter getüfftelt und nun eine Formel erstellt die so hoffe ich, alle Wünsche von Axel berücksichtigt.
Code: Alles auswählen
=WENN(UND(A10=0;B10=0;C10=0);"";GANZZAHL(MIN(WENN(A10=0;MAX(A$4:C$4)^3;A$4/A10);WENN(B10=0;MAX(A$4:C$4)^3;B$4/B10);WENN(C10=0;MAX(A$4:C$4)^3;C$4/C10))))
Viel Spaß
LG
clag
nutzt: WinXP SP3 / AOO 4.1.10 / Firefox
clag
nutzt: WinXP SP3 / AOO 4.1.10 / Firefox
-
- **
- Beiträge: 29
- Registriert: Sa, 26.04.2014 11:37
Re: Wenn Funktion 3 Werte
@@ Stephan u. Clag,
Ich danke euch für eure hilfe und eure bemühungen. Stephan, deine erklärung wie man eine Formel entwickelt, genial einfach.
Clag, deine getüfftelte formel ist genau jede die ich schon so lange gesucht habe, sie erfüllt genau jene anforderung.
Ich bedanke mich auch bei dir Hiker für deinen versuch.
Mein dank schleicht euch Ewig nach, Gruß Axel
Ich danke euch für eure hilfe und eure bemühungen. Stephan, deine erklärung wie man eine Formel entwickelt, genial einfach.
Clag, deine getüfftelte formel ist genau jede die ich schon so lange gesucht habe, sie erfüllt genau jene anforderung.
Ich bedanke mich auch bei dir Hiker für deinen versuch.
Mein dank schleicht euch Ewig nach, Gruß Axel