Kontoauszug automatisch nach Einnahmen Ausgaben

Das Tabellenkalkulationsprogramm

Moderator: Moderatoren

Carmen_261

Kontoauszug automatisch nach Einnahmen Ausgaben

Beitrag von Carmen_261 » Do, 15.11.2018 11:29

Hallo zusammen,

bitte nur Antworten wenn es einen Lösungsansatz gibt, die suche im WWW hat nach 2 wochen nicht zum erfolg geführt.
folgendes Problem:
Standard Kontoauszug mit den Spalten
Auftragskonto Buchungstag Valutadatum Buchungstext Verwendungszweck Beguenstigter/Zahlungspflichtiger Kontonummer BLZ Betrag Waehrung

Ziel:
Monat/Jahr Einnahme Ausgaben
01/2011

In Spalte Einnahmen haben ich mich mit folgendem Lösungsansatz beschäftigt
=SUMMEWENNS($'Tab1'.I2:I1000;$'3300761'.C2:C43;(MONAT($'3300761'.C2:C100)=MONAT(B3));$'Tab1'.C2:C43;JAHR($'TAB1'.C2:C100)=JAHR(B3);$'TAB1'.I2:I36;">0")

Egal was ich mache ich bekomme immer fehler, sieht einer von euch den Weg ?
Danke im Vorraus


echo
******
Beiträge: 764
Registriert: Fr, 14.11.2008 15:27
Wohnort: BRA - Nds

Re: Kontoauszug automatisch nach Einnahmen Ausgaben

Beitrag von echo » Do, 15.11.2018 13:09

Hallo Carmen
Für Summewenns() wüßte ich keine Syntax für den Monat/ das Jahr.
Unabhängig davon müssen bei summewenns() die Matrizen gleich groß sein.
$'Tab1'.I2:I1000 ; $'TAB1'.C2:C100 ; $'Tab1'.C2:C43 ; $'TAB1'.I2:I36 alles in der gleichen Formel, das kann nicht funktionieren!

Verwende =SUMMENPRODUKT() um den Monatssaldo zu berechnen:

Datum (gesuchter Monat/gesuchtes Jahr) in B3
Datum in den Kontoauszügen : $Tab1.B2:B1000
Ein-/Ausgaben in den Kontoauszügen : $Tab1.I2:I1000

Ausgaben für Monat/Jahr aus B3
=SUMMENPRODUKT((MONAT(Tab1.$B$2:$B$1000)=MONAT(B3))*(JAHR(Tab1.$B$2:$B$1000)=JAHR(B3))*(Tab1.$I$2:$I$1000<0)*(Tab1.$I$2:$I$1000))

Einnahmen für Monat/Jahr aus B3
=SUMMENPRODUKT((MONAT(Tab1.$B$2:$B$1000)=MONAT(B3))*(JAHR(Tab1.$B$2:$B$1000)=JAHR(B3))*(Tab1.$I$2:$I$1000>0)*(Tab1.$I$2:$I$1000))

Gruß Holger

Antworten