Button

Zeichnungen erstellen

Moderator: Moderatoren

op123po

Button

Beitrag von op123po » Mo, 09.12.2013 16:39

Hallo,
ich möchte einen Button erstellen und wenn ich draufklicke sollen 2 Kreise grau und ein Kreis rot werden. Wie geht das???

F3K Total
********
Beiträge: 3208
Registriert: Mo, 28.02.2011 17:49

Re: Button

Beitrag von F3K Total » Mo, 09.12.2013 17:55

Hi,
per Makro:

Code: Alles auswählen

Sub S_Fill_Circles(event)
    oButton =  event.source.model
    if oButton.label = "einfärben" then
        S_colorize_Circles
        oButton.label = "zurücksetzen"
    else
        S_uncolorize_Circles
        oButton.label = "einfärben"
    endif
end Sub

Sub S_colorize_Circles
    odrawpages = Thiscomponent.drawpages
    odrawpage = odrawpages.getbyindex(0)
    for i = 0 to odrawpage.count - 1
        oshape = odrawpage(i)
        if right(oShape.name,1) = "R" then
             oshape.FillStyle = 1
             oshape.FillColor = 16711680 'rot
        elseif right(oShape.name,1) = "G" then
             oshape.FillStyle = 1
             oshape.FillColor = 8421504 'grau
        end if
    next i
End Sub

Sub S_uncolorize_Circles
    odrawpages = Thiscomponent.drawpages
    odrawpage = odrawpages.getbyindex(0)
    for i = 0 to odrawpage.count - 1
        oshape = odrawpage(i)
        if right(oShape.name,1) = "R" or right(oShape.name,1) = "G" then oshape.FillStyle = 0
    next i
End Sub
Anbei ein Beispiel. Alle Kreise, deren Name auf R endet (siehe Navigator) werden rot, alle, deren Name auf G endet, werden grau eingefärbt.
HTH Gruß R
Dateianhänge
Kreise_einfärben.odg
(10.32 KiB) 133-mal heruntergeladen

Antworten