OpenOffice.info

Verfasst: **Mi, 15.08.2012 12:31**

Hallo Robert,

Würdet ihr bitte mal drüberschauen?

Ich hab mal reingeschaut und kann dir auch eine Lösung anbieten, gibt bestimmt noch eine andere. Doch zuvor erstmal zum Fehler.

Du hast bezüglich der Gültigkeit der Variablen dir die wichtigsten Punkte von Dannenhöfer (vermute ich) aufgeschrieben. Ist in Ordnung so. Jedoch hast Du das wohl noch nicht wirklich alles richtig verstanden.

und die Variablen sind alle als PRIVAT deklariert.

Und genau da hast Du ein verständigungsproblem, und folglich hast Du dir dadurch selber ein Bein gestellt. Mach dir nix draus, mir erging es da nicht besser.

Ich fasse jetzt mal mit meinen eigenen Worten sehr stark das zusammen, was Dannenhöfer geschrieben hat. Aber auch nur zu dem Therma PRIVATE, damit Du verstehst was da schief läuft.

Private Variablen haben nur in dem Modul ihre Gültigkeit wo sie aufgerufen werden. Wird dieses Modul verlassen, wird ihre Gültigkeit aufgehoben.

Du rufst also beim öffnen der Datei im Modul "onStart" in der Sub "onStart" das Modul "StatusFilter" die Sub "Werte_zuweisen" auf. In dem Modul "StatusFilter" werden die Variablen für dieses Modul deklariert und defeniert. Und nach dem der aufruf aus der Sub "onStart" abgearbeitet wurde, springt das Makro wieder in das Modul "onStart" zurück. Dadurch ist das Modul "StatusFilter" nicht mehr aktiv und die Variablen haben ihre Gültigkeit verloren.

Mein Vorschlag wäre jetzt; ersetze in der Sub "StatusFilter" die Private deklarationen durch GLOBAL. Dann funktionieren wengistens schon mal die "AlleAn", "AlleAus". (Getestet)
Wie gesagt, das ist ein Vorschlag meinerseits, gibt wohl auch noch bestimmt ne andere.

Gruß
balu

Verfasst: **Mi, 15.08.2012 12:50**

Hi,
habe mal einiges geändert:
1.) die Variablen global, sonst sind sie nach Durchführung eines Makros weg.

Code: Alles auswählen

Global aStatusFilter(1 to 8) as Boolean
Global aCheckboxNames(1 to 8) as String

2.) Aus den acht Makros StatusFilter... habe ich ein eventgesteuertes gemacht.

Code: Alles auswählen

Sub StatusFilter (event)
dim i as integer
ochkbox = event.source.model
nstate = ochkbox.state
    Select Case nstate
      Case 0
       i = right(ochkbox.Name,1)
       aStatusFilter(i) = true
      Case 1
       i = right(ochkbox.Name,1)
       aStatusFilter(i) = false
    End Select
End Sub

3.) Der boolean-Varialblen aStatusFilter ordne ich true und false statt 0 und 1 zu
4.) In den StatusFilter_Alle... Makros fehlte der Bezug zum Formular

Code: Alles auswählen

    oDoc = ThisComponent
    oSheet = oDoc.currentcontroller.activesheet
    oDrawPage = oSheet.DrawPage
    oForms = oDrawPage.Forms(0)

Edit: oder du deklarierst oForms auch global
ein kleiner Hinweis:
mit

Code: Alles auswählen

 oDrawPage.Forms(0)

greifst Du auf das erste Formular (Index 0) der Drawpage zu, Einzahl!
Sinnfällig wäre diese Bezeichnung, ohne s:

Code: Alles auswählen

oForm = oDrawPage.Forms(0)

oder kürzer:

Code: Alles auswählen

oForm = ThisComponent.currentcontroller.activesheet.DrawPage.forms(0)

Viel Erfolg
Gruß R

Edit: @Balu
habe gerade dran gearbeitet, als Du Deinen Beitrag geschickt hast und dies erst nach dem Absenden gemerkt.

Verfasst: **Mi, 15.08.2012 13:58**

Servus

TrueColor hat geschrieben:Style und Logik getrennt ist zwar lobenswert, aber wenn die Hierarchie der Zugriffsebenen (hm... so würde ich das jetzt mal beschreiben) unterschiedlich ist, obwohl das Kontrollelement doch ein einzelnes abgeschlossenes Modul ist (ich verwende das Kontrollelement, und nicht: ich verwende die Grafik für ein Kontrollelement und ich verwende die Logik für ein Kontrollelement), ist das meiner Meinung nach schlechtes Design.

Ich kann Dir nicht ganz folgen - das Kontrollelement ist eben *kein* "einzelnes abgeschlossenes Modul", ganz im Gegenteil, genau darum ging es doch bei Deiner letzten Frage.

Verfasst: **Mi, 15.08.2012 15:49**

Hallo,

DPunch hat geschrieben:
TrueColor hat geschrieben:Style und Logik getrennt ist zwar lobenswert, aber wenn die Hierarchie der Zugriffsebenen (hm... so würde ich das jetzt mal beschreiben) unterschiedlich ist, obwohl das Kontrollelement doch ein einzelnes abgeschlossenes Modul ist (ich verwende das Kontrollelement, und nicht: ich verwende die Grafik für ein Kontrollelement und ich verwende die Logik für ein Kontrollelement), ist das meiner Meinung nach schlechtes Design.
Ich kann Dir nicht ganz folgen - das Kontrollelement ist eben *kein* "einzelnes abgeschlossenes Modul", ganz im Gegenteil, genau darum ging es doch bei Deiner letzten Frage.

Ja eben, deshalb hatte ich ja solche Probleme damit, weil ich dachte, es wäre ein einzelnes. Das es anders ist, auf diesen Trichter bin ich erst durch eure Hilfe gekommen, deshalb auch meine verwunderte Frage, die du ja bestätigt hast.

balu hat geschrieben:Und nach dem der aufruf aus der Sub "onStart" abgearbeitet wurde, springt das Makro wieder in das Modul "onStart" zurück. Dadurch ist das Modul "StatusFilter" nicht mehr aktiv und die Variablen haben ihre Gültigkeit verloren.

Na toll, daran hatte ich nicht gedacht! Ich hatte schon kurz den Gedanken, mal mit GLOBAL zu testen, aber nur so just for fun. Ich wollte die Module möglichst getrennt halten, hatte mich deshalb für PRIVATE entschieden.

Oder ist PUBLIC besser als GLOBAL? Ich schätze das Risiko bei GLOBAL relativ hoch ein, das irgendetwas kollidiert, ist so ein Bauchgefühl.

Gibt es denn eine andere Möglichkeit, wie ich mehrere Macros beim Laden des Dokuments starten kann, ohne die jeweiligen Module verlassen zu müssen? Ich würde gern bei PUBLIC bleiben, weil ich dann nicht immer die anderen Module auf Kollision prüfen müsste.

DPunch hat geschrieben:2.) Aus den acht Makros StatusFilter... habe ich ein eventgesteuertes gemacht.

Damit hast du mir vorgegriffen. Die Optimierung dieser Sache lag mir auch noch am Herzen. Werde ich mir anschauen!

Kannst du mir i = right(ochkbox.Name,1) näher erläutern? Was macht right?
(Edit: der Papiergroschen ist gelandet: Teilstring von rechts, Länge = 1 Zeichen)

DPunch hat geschrieben:3.) Der boolean-Varialblen aStatusFilter ordne ich true und false statt 0 und 1 zu

Was sind die Vorteile? Von der Lesbarkeit finde ich 0/1 besser.

DPunch hat geschrieben:greifst Du auf das erste Formular (Index 0) der Drawpage zu, Einzahl!
Sinnfällig wäre diese Bezeichnung, ohne s

Klingt sinnvoll, damit erschliesst sich dem Lesenden der Code besser.

Vielen Dank euch allen!

Verfasst: **Mi, 15.08.2012 19:18**

Servus

TrueColor hat geschrieben:Ja eben, deshalb hatte ich ja solche Probleme damit, weil ich dachte, es wäre ein einzelnes. Das es anders ist, auf diesen Trichter bin ich erst durch eure Hilfe gekommen, deshalb auch meine verwunderte Frage, die du ja bestätigt hast.

Dann hatte ich Dich da anscheinend missverstanden, Dein letztes Statement hat sich für mich so angehört, als würdest Du es als schlechtes Design betrachten, weil das Kontrollelement ja schliesslich ein abgeschlossenes Modul sei. Nichts für ungut.

TrueColor hat geschrieben:Was sind die Vorteile? Von der Lesbarkeit finde ich 0/1 besser.

Über die Lesbarkeit kann man sich sicher streiten (ich persönlich finde, FALSE/TRUE sorgt für deutlich mehr Lesbarkeit), im Hinterkopf behalten muss man dabei allerdings immer:
1 ist ungleich TRUE. Die interne Repräsentation von TRUE ist -1.

Code: Alles auswählen

	MsgBox (1 = TRUE)		'FALSE
	MsgBox (1 = FALSE)		'FALSE
	MsgBox (NOT 1 = TRUE)	'FALSE
	MsgBox (NOT 1 = FALSE)	'FALSE

Verfasst: **Do, 16.08.2012 07:23**

DPunch hat geschrieben:Die interne Repräsentation von TRUE ist -1.

-1? Ok, dann ist TRUE/FALSE tatsächlich besser.

Verfasst: **Do, 16.08.2012 08:49**

Hallo,

nachdem ich jetzt die Optimierung der einzelnen Checkboxen auch auf die beiden Buttons angewendet habe, fkt. das jetzt alles einwandfrei.

Code: Alles auswählen

REM  *****  BASIC  *****

' -------------------------
'   öffentliche Variablen
' -------------------------
' werden im Kopfbereich deklariert
'
' Gültigkeit globaler Variablen:
' GLOBAL: innerhalb der gesamten Staroffice-Sitzung in allen geladenen Bibliothken, Modulen, Prozeduren und Funktionen
' PUBLIC: innerhalb aller Module einer Bibliothek
' PRIVATE: innerhalb eines Moduls, diese Variablennamen können daher auch in mehreren Modulen parallel verwendet werden
'
Global aStatusFilter(1 to 8) as Boolean
Global aCheckboxNames(1 to 8) as String

Private oForms as Object

' ------------------
'   Werte_zuweisen
' ------------------
' Beschreibung: Den öffentlichen Variablen Werte zuweisen, Array und Checkboxen initialisieren
' benötigte Macros: keine
'
Sub Werte_zuweisen

    Dim i as Integer 'Laufvariable

    oForm = ThisComponent.CurrentController.ActiveSheet.DrawPage.Forms(0)
    
    aCheckboxNames(1) = "Chk_StatusFilter1"
    aCheckboxNames(2) = "Chk_StatusFilter2"
    aCheckboxNames(3) = "Chk_StatusFilter3"
    aCheckboxNames(4) = "Chk_StatusFilter4"
    aCheckboxNames(5) = "Chk_StatusFilter5"
    aCheckboxNames(6) = "Chk_StatusFilter6"
    aCheckboxNames(7) = "Chk_StatusFilter7"
    aCheckboxNames(8) = "Chk_StatusFilter8"
    
    for i = 1 to 8
      oForm.getByName(aCheckboxNames(i)).State = 1
      aStatusFilter(i) = true
    next

End Sub

' ---------------------
'   StatusFilter_Alle
' ---------------------
' Beschreibung: schaltet alle Checkboxen an/aus
' benötigte Macros: keine
'
Sub StatusFilter_Alle (Event)

    Dim oButton as Object
    Dim i as Integer
    
    oForm = ThisComponent.CurrentController.ActiveSheet.DrawPage.Forms(0)
    oButton = Event.Source.Model

    Select Case oButton.Name
      Case "Btn_StatusFilter_AlleAn"
        for i = 1 to 8
          oForm.getByName(aCheckboxNames(i)).State = 1
          aStatusFilter(i) = true
        next
      Case "Btn_StatusFilter_AlleAus"
        for i = 1 to 8
          oForm.getByName(aCheckboxNames(i)).State = 0
          aStatusFilter(i) = false
        next
    End Select

End Sub

' ----------------
'   StatusFilter
' ----------------
' Beschreibung: schaltet die einzelnen Checkboxen an/aus
' benötigte Macros: keine
'
Sub StatusFilter (Event)

    Dim oChkBox as Object
    Dim i as Integer

    oChkBox = Event.Source.Model

    Select Case oChkBox.State
      Case 0
        i = right(oChkBox.Name,1)
        aStatusFilter(i) = true
      Case 1
        i = right(oChkBox.Name,1)
        aStatusFilter(i) = false
    End Select

End Sub

Nochmals vielen Dank euch allen für eure Geduld.

Jetzt kann ich mich an die eigentlichen Filter machen. Hm... ich werde mich dann sicher wieder melden müssen. Mal sehen, wie weit ich komme

Verfasst: **Do, 16.08.2012 11:23**

Moin,
das sieht doch super aus!
Mit Transferleistung!
1+
Einen Tipp möchte ich Dir noch geben:
Ich habe das

Code: Alles auswählen

i = right(oChkBox.Name,1)

verwendet, weil Du alle Markierfelder so schön gleichmäßig benamst hast und es weniger als 10 Stück sind.
Normalerweise verwende ich für diesen Fall

Code: Alles auswählen

i = event.source.model.tag

und trage die auszulesende Zahl/Text dann unter den Eigenschaften/Allgemein/Zusatzinformation des jeweiligen Feldes ein.

Beste Grüße R

Verfasst: **Do, 16.08.2012 12:02**

F3K Total hat geschrieben:Einen Tipp möchte ich Dir noch geben:
Ich habe das
Code: Alles auswählen
i = right(oChkBox.Name,1)
verwendet, weil Du alle Markierfelder so schön gleichmäßig benamst hast und es weniger als 10 Stück sind.

Bei mehr als 9 verwende ich dann auch 2 Stellen, weil ich diesen Stellensprung hasse

Normalerweise verwende ich für diesen Fall
Code: Alles auswählen
i = event.source.model.tag
und trage die auszulesende Zahl/Text dann unter den Eigenschaften/Allgemein/Zusatzinformation des jeweiligen Feldes ein.

Oh, da kann man eigene Tags vergeben? Muss ich mir merken, klingt nützlich!

OpenOffice.info

[gelöst] Checkbox getByName()

Re: Checkbox getByName()

Re: Checkbox getByName()

Re: Checkbox getByName()

Re: Checkbox getByName()

Re: Checkbox getByName()

Re: Checkbox getByName()

Re: Checkbox getByName()

Re: [gelöst] Checkbox getByName()

Re: [gelöst] Checkbox getByName()