OpenOffice.info

Code: Alles auswählen

Sub Grafiken_auslesen
Dim odoc as Object, grafiken as object, oURL as object, oTxt as Object
Dim s as string

odoc=thisComponent

 grafiken=odoc.getGraphicObjects()
 oObjects=odoc.getEmbeddedObjects()

REM Bilder in einer Schleife auslesen

	s = Chr(13) & " Verzeichnis der Bildreferenzen:" & CHR(13) & CHR(13)
 		for i= 0 to grafiken.count -1
		oURL = grafiken.getByIndex(i)
	s = s & "Abb." & i+1 & " : " & oURL.graphicUrl & chr(13) '& oURL.name  & " - "
 next

REM Einfügen am Ende des Textes

oTxt = oDoc.text
oTxt.insertString(oTxt.getEnd(), s + chr(13) + "Ende Bildreferenzen", False)
oTxt.insertControlCharacter(oTxt.getEnd(), com.sun.star.text.ControlCharacter.APPEND_PARAGRAPH, False)
oDoc.refresh()

msgBox "Bildreferenzen am Ende des Dokuments eingefügt", 64, "Bilder auslesen aus Text"

End Sub

Code: Alles auswählen

Sub GrafikRahmen_beschriften
Dim odoc as Object, grafiken as object, oURL as object

BasicLibraries.loadLibrary("Tools") 'Diese Biblothek brauchst Du für das Auslesen des Dateinamens

 odoc=thisComponent

    '*** oFrame=oDoc.getTextFrames()
    '*** die vorherige Zeile brauchst Du für die Alternative (s.u.)

 grafiken=odoc.getGraphicObjects()

REM *** Bilder in einer Schleife auslesen

for i= 0 to grafiken.count -1
		oURL = grafiken.getByIndex(i)
		oURL.getAnchor.TextFrame.String="Abb. " + i+": "+ FileNameOutOfPath(oURL.graphicUrl)

    ' *** alternativ (wenn keine anderen TextFrames vorhanden sind geht aus das hier):
    ' *** oFrame.getByIndex(i).String="Abb. " + i+": "+ FileNameOutOfPath(oURL.graphicUrl)
next

End Sub

Code: Alles auswählen

Sub BilderEinfuegenPlusBookmark

DIM Array()

oDoc=ThisComponent

oFolderDlg = createUnoService("com.sun.star.ui.dialogs.FolderPicker")
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")
DIM oSize as new com.sun.star.awt.Size

document   = oDoc.CurrentController.Frame

sfolder=oFolderDlg.execute()
sPfad=ConvertFromUrl(oFolderDlg.Directory)
sDatei=Dir(sPfad+"\*.jpg",0)

do

	REM *** Auslesen des nächsten Bildes
		sDatei=Dir$
		
	REM *** ans Ende des Dokumentes gehen und.....
		oPos=oDoc.Text.getEnd()
	
	REM *** Dateiname einfügen
		oPos.string= sDatei
	
	REM *** Zeilenformatierung "Überschrift" (für das Inhaltsverzeichnis bzw. die Bookmarks als PDF Datei erforderlich)
		CALL ZeilenFormat

	REM *** Bild einfühen
		oBild = oDoc.createInstance( "com.sun.star.text.GraphicObject")
		oBild.GraphicURL=convertToURL(sPfad+"\"+sDatei)
	
	REM *** Größe setzen
		oSize.Width=17100
		oSize.Height=24930
		oBild.setSize(oSize)

	REM ...das einfügen des Bildes	
		oDoc.Text.insertTextContent(oPos, oBild, false )
		
	REM *** Seitenwechsel einfügen
		dispatcher.executeDispatch(document, ".uno:InsertPagebreak", "", 0, Array())
	
Loop While sDatei<>""

end Sub

'###########################################

sub ZeilenFormat

dim document   as object
dim dispatcher as object
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

dim args1(1) as new com.sun.star.beans.PropertyValue
args1(0).Name = "Template"
args1(0).Value = "Überschrift 1"
args1(1).Name = "Family"
args1(1).Value = 2

dispatcher.executeDispatch(document, ".uno:StyleApply", "", 0, args1())

end sub

'###########################################

Code: Alles auswählen

...
Size.Width=17100 (d.h. 17,1 cm)
oSize.Height=24930 (d.h. 24,93 cm)
...